赋予 Session 对象，这些数据在 HTTP 调用中将保留在内存中。Session 数据按用户存储，而 Application 数据在所有用户间共享。
何时将数据载入 Application 或 Session？通常，在 Application 或 Session 启动时加载数据。要在 Application 或 Session 启动时加载数据，请在下面两函数中添加相应的代码：
Application_OnStart()
或
Session_OnStart()
。这两个函数应该位于 Global.asa；如果没有，可以添加这些函数。也可以在第一次需要数据时加载数据。要进行上述操作，请在 ASP 页中添加一些代码（或编写可重用的脚本函数），这些代码检查数据是否存在，并在数据不存在时加载数据。这是称为迟缓计算的经典性能技术的例子 - 在您的确需要它之前，不进行计算。请看例子：
<%
Function GetEmploymentStatusList
Dim d
d = Application("EmploymentStatusList")
If d = "" Then
'' FetchEmploymentStatusList 函数（不显示）
'' 从 DB 中取出数据，返回数组
d = FetchEmploymentStatusList()
Application("EmploymentStatusList") = d
End If
GetEmploymentStatusList = d
End Function
%>
可以为每一块所需的数据编写类似的函数。
数据应该以什么格式存储？任何变量类型均可存储，因为所有脚本变量是各不相同的。例如，可以存储字符串、整型或数组。通常，您将以这些变量类型之一存储 ADO 记录集的内容。若要获取 ADO 记录集衍生的数据，可以手工将数据复制到 VBScript 变量中，每次一个字段。使用一个 ADO 记录集保留函数 GetRows()、GetString() 或 Save() (ADO 2.5)，会更快更简便。完整而详细的内容已超出了本文的范围。下面的演示函数使用了
GetRows()
来返回记录集数据的数组：
'' 取记录集，以数组返回
Function FetchEmploymentStatusList
Dim rs
Set rs = createObject("ADODB.Recordset")
rs.Open "select StatusName, StatusID from EmployeeStatus", _
"dsn=employees;uid=sa;pwd=;"
FetchEmploymentStatusList = rs.GetRows() '' 以数组返回数据
rs.Close
Set rs = Nothing
End Function
对上面示例的进一步改进应当是缓存该列表的 HTML，而不是缓存数组。下面是一个简单的范例：
'' 取记录集，以"HTML 选项"列表返回
Function FetchEmploymentStatusList
Dim rs, fldName, s
Set rs = createObject("ADODB.Recordset")
rs.Open "select StatusName, StatusID from EmployeeStatus", _
"dsn=employees;uid=sa;pwd=;"
s = "<select name=""EmploymentStatus">" & vbCrLf
Set fldName = rs.Fields("StatusName") '' ADO 字段绑定
Do Until rs.EOF
'' 下面一行违背了不要进行字符串连接，
'' 但这是可以的，因为我们正在建立高速缓存
s = s & " <option>" & fldName & "</option>" & vbCrLf
rs.MoveNext
Loop
s = s & "</select>" & vbCrLf
rs.Close
Set rs = Nothing '' 参见尽早释放
FetchEmploymentStatusList = s '' 以字符串返回数据
End Function
在正常的情况下，可以在 Application 或 Session 作用域中缓存 ADO 记录集本身。有两个警告：
ADO 必须为标记的自由线程
必须使用断开连接的记录集。
如果不能保证满足这两个要求，请不要缓存 ADO 记录集。在下面的非灵活组件和不要缓存连接技巧中，我们将讨论在 Application 或 Session 作用域中存储 COM 对象的危险。
如果在 Application 或 Session 作用域中存储数据，这些数据将一直保留在那儿，直到在程序中改变它、Session 过期或 Web 应用程序重新启动时为止。数据需要更新如何处理？若要用手工强制更新应用程序数据，可以调用只允许管理员访问的数据更新 ASP 页。
