一个asp快速字符串连接类

本文主要为广大网友提供“一个asp快速字符串连接类”，希望对需要一个asp快速字符串连接类网友有所帮助，学习一下!

<%
''%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
''快速字符串连接类
''%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
''名称：Class_FastString
''来源：http://www.jansfreeware.com
''整理：qihangnet
''更新：2005年6月15日
''作用：高效地进行字符串连接，比 str = str & "abc"的方法快很多
''授权：免费使用
''%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

Class Class_FastString

''************************************
''变量定义
''************************************
''index --- 字符串数组的下标
''ub ------ 用于调整数组度数的整数变量
''ar() ---- 字符串数组

Private index, ub, ar()

''************************************
''实例 初始化/终止
''************************************

Private Sub Class_Initialize()
Redim ar(50)
index = 0
ub = 49
End Sub

Private Sub Class_Terminate()
Erase ar
End Sub

''************************************
''事件
''************************************

''默认事件，添加字符串
Public Default Sub Add(value)
ar(index) = value
index = index+1
If index>ub Then
ub = ub + 50
Redim Preserve ar(ub)
End if
End Sub

''************************************
''方法
''************************************

''返回连接后的字符串
Public Function Dump
Redim preserve ar(index-1)
Dump = join(ar,"") ''关键所在哦^_^
End Function

End class
%>